ASP/IIS可安装组件一

80酷酷网    80kuku.com

　　iis


    ASP/IIS的标准安装包括一系列服务器组件，这些组件在IIS文档中被描述为可安装组件（installable component），尽管缺省状态下它们是安全安装。但也有可能这个名称仅仅是沿用ASP的前几个版本中的名字。在以前版本中，这些组件需要人工安装。现在，如果要给它们起个合适的名称，可称为“可实例化的组件”。
       需要注意的是，在第8章将介绍一个特定的可安装组件，即ADO组件。后面的章节中使用的其他组件都是作为特定的服务或服务器应用程序的一部分而安装的。例如协作数据对象（Collaborative Date Objects，简称CDO和CDONTS）组件，用于邮件服务器和电子邮件消息。本章的其余部分将讨论，如何使用其他通用性较强的组件为Web网站或Intranet提供增强功能。
       在Windows 2000中的WinNTSystem32intesrv目录下可找到这些ASP可安装组件，该目录也放置一些组件要求的配置文件。下面按字母顺序列出了一些组件。
       · Ad Rotator组件用于控制可点击图像的出现，如广告或标题。使用存储在配置文件中的信息，Ad Rotator能够依据配置文件规定的比率显示不同的图像，同时也具备把可点击的广告重新定位到相应的URL以及记录图像点击次数的特性。
       · Browser Capabilities组件使用UserAgent字符串，该字符串由浏览器发往服务器，用来识别相应的浏览器。它提供了反映特定浏览器功能的一系列属性，例如是否支持脚本、cookie或Java小程序。
       · Content Linking组件用于提供一系列方便导航的页面，这些页面可被改变或更新而不必编辑各个页面。该组件采用一个文本文件（含有页面URL和显示顺序），使创建按指定顺序链接起来的一些页面很容易。
       · Content Rotator组件采用一种配置文件来指定插入到其他页面中的HTML、文本或程序代码，根据配置文件指定的情况，显示内容的任何部分。
       · Counters组件能够创建、递增和永久地存储各个在脚本代码中使用的整数计数器的数值。
       · Logging Utility组件提供对Web服务器日志文件的访问，并且允许在一个ASP页面内读取和更新这些数据。这是Windows 2000中随IIS 5.0和ASP 3.0新增的特性。
       · MyInfo组件为可在整个网站内访问的名称/值对的存储提供了一个存储空间，这些数据在服务器上以XML格式的文本文件存储（不同于应用程序作用域，这些数据在Web网站范围之外仍然保留）。
       · Page Counter组件记录访问一个页面的次数，可以用于跟踪页面的点击次数。
       · Permission Checker组件有助于防止当一个用户试图访问没有正确的权限设置的资源时引起的脚本错误。
       · Tools组件提供了一些在页面中可以采用的方法，这些方法用于检验一个文件是否存在、处理HTML窗体、生成一个随机整数。另外还有一些用在Macintosh苹果计算机上的方法，可以检查是否存在某个服务器插件程序，检查当前用户是否为网站拥有者。
       另外一个由IIS/ASP提供的组件，即Status组件，只能用于Macintosh计算机的个人Web服务器上。本书没有涉及该组件，若要详细了解该组件，可通过HTTP://localhost/iis/htm/asp/complqt0.htm查阅ASP/IIS提供的IIS 5.0文档。

6.2.1 使用示例页面
       本书已经提供了一系列的示例页面来说明所有这些组件的用法。
       可以从Wrox Web网站上下载这些实例页面，并在自己的计算机上运行。在下载的文件的Chapter06子目录中会找到本章所用的程序代码。
       在运行示例页面之前，确保MyInfo和Counter组件的“全局”实例化代码已包含在缺省Web站点的global.asa文件中。在示例文件中提供了global.asa文件中所需要的代码，可以将这些代码加到现有的global.asa文件中，不需要更换整个文件。
<!-- declare instance of the ASP Counters component with application-level scope
-->
<OBJECT ID="objCounters" RUNAT="Server" SCOPE="Application"
PROGID="MSWC.Counters">
</OBJECT>

<!-- declare instance of the ASP MyInfo component with application-level scope
-->
<OBJECT ID="objMyInfo" RUNAT="Server" SCOPE="Application" PROGID="MSWC.MyInfo">
</OBJECT>
示例文件的主菜单页面（Default.asp）使用Content Linking组件创建到每一个页面示例的链接。因此，我们将首先研究这个组件，也涉及了Ad Rotator和Counters组件的有关问题。

6.2.2 Content Linking组件
       Content Linking组件对网站是非常有用的工具，它提供了内容页面，或者包含对同一站点上其他页面的链接列表的页面。它自动把当前显示页面的URL与存储在服务器里的文本文件的页面列表匹配起来并且能允许用户通过页面列表按正反顺序进行浏览。也就是说，即使访问者已经在内容页面中点击了一个链接并且正在查看列表中的某一个页面，该组件仍然会辨认出所访问的页面在列表中的位置。
       因为所有详细资料均在一个文本文件中，维护网站以及页面的链接仅仅需要编辑这个文本文件。例如可以通过在内容链接列表文件中重新排列页面的顺序，来改变它们的显示顺序。
1．  内容链接列表的文件
内容链接列表文件包括一个简单的按显示顺序排列的URL列表，同时也提供了相应的描述，用于在内容页面中显示链接文本。如果需要，还可以增加对每个页面的注释，注释可以帮助识别链接，但对访问者来说注释是不可见的。
列表文件对于每个页面包含一个文本行。每一行由URL、描述和注释所组成，各部分由Tab字符（不是空格，否则文件将不能工作）分隔，最后有回车结束。例如：
newpages.htm        New additions to our site              we update this weekly
offers.htm            Special Offers for this week         we only update this monthly
register.htm           Registration for new users
main.htm               The main forum and chat area      must be registered first
index.htm              Back to the contents page
请注意目标URL必须由一个相对的虚拟或物理的路径来说明，诸如forumenter.htm。URL不能使用“http:”、“//”或者“\”作为开头，如果要创建上述这样含有绝对URL的菜单，可以使用ASP建立一个重新定向页面，而且在内容链接列表文件中对其进行指定，例如，建立一个名为redirect.asp的页面，包含如下代码：
<%
'redirect the request to the site specified in the query string
Response.Clear
Response.Redirect Request.QueryString("url")
%>
可以在内容链接列表文件中按下述方式使用redirect.asp文件：
redirect.asp?url=http://www.cyscape.com/         CyScape BrowserHawk Web Pages
redirect.asp?url=http://www.softartisans.com/     SA fileUp Component Pages
redirect.asp?url=http://www.stonebroom.com/swindex.htm              Stonebroom RegEx Pages
2．  Content Linking组件的成员
Content Linking组件提供了八种方法，如表6-1所示。这些方法能够检索来自内容链接列表文件的条目，既能相对于当前页面检索条目，也可以使用索引号检索绝对条目。第一个条目的索引号是1。
表6-1  Content Linking组件的方法及说明
方 法
说 明

GetListCount(links_file)
返回文件links_file中条目的数量

GetListIndex(links_file)
返回文件links_file中当前页面的索引号

GetNextURL(links_file)
返回文件links_file中下个页面的URL

GetNextDescription(links_file)
返回文件links_file中下个页面的描述

GetPreviousURL(links_file)
返回文件links_file中前一个页面的URL

GetPreviousDescription(links_file)
返回文件links_file中前一个页面的描述

GetNthURL(links_file,n)
返回文件links_file中第n个页面的URL

GetNthDescription(links_file,n)
返回文件links_file中第n个页面的描述

       如果当前页面不在内容链接列表文件中，则：
       · GetListIndex返回0。
       · GetNextURL和GetNextDescription返回列表文件中最后一个页面的URL和描述。
       · GetPreviousURL和GetPreviousDescription返回列表文件中第一个页面的URL和描述。
3．  使用Content Linking组件
一旦创建了自己的内容链接文件，就可以把该组件添加到页面中。这里有一个典型的示例，它遍历内容链接文件中的所有条目，并且创建一个页面列表（以超链接表示页面）。
<% ' in VBScript:
Set objNextLink = Server.CreateObject("MSWC.Nextlink")
%>

<UL>
<%
'get the number of entries in the menu file
intCount = objNextLink.GetListCount("contlink.txt")
'loop through the entries
For intLoop = 1 To intCount %>
       <LI>
       <A HREF="<% = objNextLink.GetNthURL("contlink.txt", intLoop) %>">
       <% = objNextLink.GetNthDescription("contlink.txt", intLoop) %>
       </A>
<%
Next
%>
</UL>
这段代码首先创建了一个Content Linking对象。在普通的<UL>和</UL>标记之间，使用Content Linking对象的GetListCount方法查找在内容链接列表文件有多少条目。然后再遍历这些条目，对于每一个条目在页面中放入一个<LI>标记，后面跟着一个<A>标记。HREF属性的值从列表文件中使用GetNthURL方法检索得到，用作链接文本的描述使用GetNthDescription方法得到。
注意，内容列表文件和使用它的ASP页面应处在同一文件夹中。否则，应提供一个相对物理路径或一个完整的虚拟路径，如下所示：
inCount = objNextLink.GetListCount("linkscontlink.txt")           'physical path
inCount = objNextLink.GetListCount("/demo/contlink.txt")        'virtual path
(1)    创建一个内容页面
我们已经使用Content Linking组件为本章提供的示例创建了菜单页面。Chapter06文件夹中的页面Default.htm采用上述代码创建菜单，如图6-2所示：

       可以看到内容链接列表文件的内容显示在链接的下面，我们使用FileSystemObject对象完成这一工作。
       <%
       'create an instance of a FileSystemObject object
       Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

       'open the text file as a TextStream object
       Set objTStream = objFSO.OpenTextFile(Server.MapPath("contlink.txt"), ForReading)
       Response.Write objTStream.ReadAll                          'read the whole file and put into page
       ObjTStream.Close
       %>
       如果你编辑了contlink.txt文件，下次再次调用这个页面时，会看到菜单的条目发生了变化。注意文件中的最后三个条目，这三个条目使用前面介绍的redirect.asp技术，把绝对（而不是相对）的URL插入到列表中。
(2)    浏览这些页面
创建一个Content Linking组件实例并且使用它的一个方法时，将把当前页面的URL与指定的内容链接列表文件中的条目相匹配。不仅能用该组件创建一个内容列表（就像刚看到的那样），而且当在浏览器上打开其中一个页面时，可以用该组件对列表中的各个页面进行导航。
这意味着可以用超链接或按钮从这些页面中的一个移到另一个。例如，可以给页面添加Next和Back按钮，通过使用GetNextURL和GetPreviousURL方法能知道列表中的哪一个页面是前一个，哪一个页面是下一个。另一方面，能用GetNthURL方法跳到列表中的任何页面，用GetListIndex方法能知道当前页面在列表中的位置。
下面是一段给页面添加Next和Back按钮的代码，我们要做的只是把这段程序放在内容链接文件所列出的每一页中，或者用SSI的#include指令将它插入其中。
<!-- need a form to force Navigator to display the buttons -->
<FORM ACTION="">
<%
'we'll insert this into each page using an SSI #include statement
'create an instance of the Content Linking component
Set objNextLink = Server.CreateObject("MSWC.NextLink")
'set the content linking list file path and name
strListFile = "contlink.txt"
'get the index of the current page in the list
intThisPage = objNextLink.GetListIndex(strListFile)
If intThisPage > 1 Then  'can go back
%>
  <INPUT TYPE=BUTTON VALUE="< Back"
     ONCLICK="location.href='<% = objNextLink.GetPreviousURL(strListFile) %>';"
     TITLE="Go to '<% = objNextLink.GetPreviousDescription(strListFile) %>'">
   
<%
End If
%>
<INPUT TYPE=BUTTON VALUE=" Menu " ONCLICK="location.href='Default.asp';"
       TITLE="Return to the main 'Installable Components' menu">
<%
If intThisPage < objNextLink.GetListCount(strListFile) Then  'can go forward
%>
   
  <INPUT TYPE=BUTTON VALUE="Next >"
         ONCLICK="location.href='<%= objNextLink.GetNextURL(strListFile) %>';"
         TITLE="Go to '<% = objNextLink.GetNextDescription(strListFile) %>'">
<%
End If
%>
</FORM>
第一步是创建Content Linking组件，然后把列表文件名存入一个变量中，以便后面在创建页面里的客户端JScript代码时能够使用这个列表文件。另外这样做也便于页面的维护，因为如果想使用一个不同文件名仅需在一个地方改变就可以了。
现在让我们了解一下在链接列表中所处的位置。GetListIndex方法提供当前页面的索引号，从列表中的第一页开始。如果当前页面的索引号比1大，那么可以后退，所以我们在页面中创建Back按钮。如果当前页面的索引号比列表中的项数少，创建Next按钮。页面中总是包括一个Home按钮，以便访问者在任何时候都能轻易地返回到内容页面。
如果打开列在主菜单中的页面之一的话，将会看到使用这项技术在每个页面上创建的一系列导航按钮，创建按钮的代码在文件contlinkbuttons.inc中，可用#include指令将它插入每个页面中。图6-3所示为带有按钮的界面。

       在图6-3中有三个按钮，使用GetPreviousDescription方法获得上个页面的链接文件，并把这个文本放入Back按钮的TITLE属性中，作为弹出的提示。
       <INPUT TYPE=BUTTON VALUE="< Back"
ONCLICK="location.href='<% = objNextLink.GetPreviousURL(strListFile) %>';"
          TITLE="Go to '<% = objNextLink.GetPreviousDescription(strListFile) %>'">
       Next按钮采用GetNextDescription方法完成类似的工作。
(3)    用JavaScript跳转
这些导航按钮使用JavaScript（而不是VBScript）装载新页面，这样就能够和大多数现代浏览器兼容。例如Back按钮包含下面的属性：
ONLICK="location.here='<% = objNextLink.GetPreviousURL(strListFile) %>'; "
当页面的HTML版本由ASP创建时，在<%…%>标记中的表达式用其数值取代，所以发往浏览器的网页看起来如下所示：
ONCLICK="location.herf='permissionchecker.asp'; "
为什么选择使用变量来表示内容链接列表文件的名字？其原因是在单个语句中包括一个三层的嵌套引用是非常麻烦的。
注意浏览器的缺省语言是JavaScript（或IE中的JScript），而不是VBScript，通过使用JavaScript，可以避免在OnClick代码中必须提供LANGUAGE参数，同时对非IE浏览器提供兼容性。

6.2.3 Ad Rotator组件
       Ad Rotator组件允许浏览器在引用ASP页面时每次显示不同的图像，这项技术经常用在显示广告的站点上。每次打开或重新载入页面时，ASP采用“旋转调度文件”(rotator schedule file)中的信息选择一副图像，并插入网页中。然而Ad Rotator组件能做更复杂的工作，它可以把图像设置成超级链接而不是一副静止的图像，并能记录用户对每个广告的点击次数。
       在本章所介绍的组件中，Ad Rotator组件可能是最难使用的，因为它涉及几个不同的文件。在查看每个文件之前，图6-4所示的工作过程总览可能有助于了解它们之间的组合方式。

1．  旋转调度文件
Ad Rotator组件依赖于该文件来指定显示的广告或图像。这个文件包括每个图像文件的名字、显示的尺寸大小以及显示时间的相对百分数。该文件分为两部分，由一个仅含有一个星号（*）的行分隔。
文件格式如下：
REDIRECT URL
WIDTH width
HEIGHT height
BORDER border
*
adURL
adHomeURL
text
impressions
其中：
· URL是执行重新定向的ASP文件或程序的虚拟路径及名称。
· width和height定义了页面中广告条的大小（以像素为单位），缺省值为440×60。
· border规定了广告条边界的宽度（以像素为单位），缺省值为1，无边界时为0。
第一部分是可选的，设置应用于该文件中所有广告条的缺省值。这给设置所有图像的参数提供了一种方法，边界宽度可以使用Ad Rotator组件中的border属性来设置。如果忽略了一项或多项此类任选参数，而且没有明确设置对象属性，那么参数就使用其本身和缺省值。如果忽略所有这些参数，仍需包含“*”作为文件的第一行。
第二部分，即“*”后的部分，必须存在于该文件中，它提供了各个广告条的细节。对于每个广告条，下面四个参数要重复使用。这些参数是：
· adURL，是广告图像文件的虚拟路径和文件名。
· adHomeURL，是广告跳转到的URL，连字符（-）表明该广告条没有链接。
· text，浏览器不支持图型文件时显示的文本。
· impressions，是一个整数，指明了此广告条显示的相对时间或时间比率，例如一个文件包含三个广告条，而且它们的impressions值分别设置为4、6和10，那么表明返回的页面中有20%可能出现第一个广告条，30%出现第二个广告条，50%出现第三个广告条。这没有指明广告条在浏览器中显示的实际时间。注意每一个广告条的实际出现是随机的，并被修改以达到需要的比率。
下面看一个重新定向文件的例子：
REDIRECT AdRotFiles/ad_redirect.asp
WIDTH 400
HEIGHT 50
*
Adrotfiles/wrox.gif
http://www.wrox.com/
Better Books from Wrox press
3
AdRotFiles/lunar.gif
http://www.going-to-the-moon.com/store.asp
Acme Lunar Boost Supplies
1
2．  Ad Rotator组件的成员
Ad Rotator组件含有一个方法和三个属性，方法如表6-2所示：
表6-2  Ad Rotator组件的方法及说明
方 法
说 明

GetAdvertisement(schedule_file)
使用指定的schedule_file中的信息创建并返回一个字符串，这个字符串含有把下一个合适的图像插入到该页面所需的HTML

       属性如表6-3所示：
属 性
说 明

Border
整数型，是指广告条边界的宽度（以像素为单位），若未设定，则采用文件第一部分设定的值

Clickable
布尔型，规定广告栏图像文件是否显示为一个超级链接，缺省值为True

TargetFram
字符串型，目标框（frame）的名字。如果用户点击图像文件的话，这个框用于显示广告主的页面。如果忽略的话，页面装载到当前浏览器的目标框或窗口内，取代含有广告栏图像的页面，这个属性也能设置成一个标准的HTML框标识：_top、_new、_child、_self、_parent和_blank

3．  使用Ad Rotator组件
下面的代码说明了Ad Rotator组件的使用。创建了组件实例之后，设置属性参数并调用GetAdvertisement方法，指定调度文件的相对物理路径。由组件返回的HTML代码通过使用Response.Write方法插入到页面中。
<%  'VBScript example
QUOT = Chr(34)
Set objAdRot = Server.CreateObject("MSWC.AdRotator")
objAdRot.Border=0                   'no border
objAdRot.Clickable=TRUE             'is a hyperlink
objAdRot.TargetFrame="fraAdFrame"   'load into new window named fraAdFrame
strHTML = objAdRot.GetAdvertisement("AdRotFilesad_schedule.txt")
Response.Write(strHTML)             'put the HTML into the page
%>
GetAdvertisement方法的参数是相对于当前目录或Web网站根目录的调度文件物理路径和文件名。在上面的代码中，此文件取名为AdRotFiles，位于包含正在运行的ASP页面的当前目录下的子目录中。如果这个文件存入Web网站根目录下的AdRotFiles子目录，应使用“AdRotFilesMyAdFile.txt”。
调用GetAdvertisement方法时，返回能插入网页中用于创建广告栏的HTML代码，对于上例中的旋转调度文件中的第一个广告栏，可以得到下列代码：
<A HREF="/AdRotFiles/AdRedirect.asp?
       url=http://www.wrox.com/&image=/AdRotFiles/AdPics/wrox.gif">
<IMG SRC=http://www.163design.net/a/j/"/AdRotFiles/AdPics/wrox.gif"
       ALT="Better Books from Wrox Press" WIDTH=440 HEIGHT=60 BORDER=0></A>
可以看到在常规的<A>标记中放置了图像文件，HREF属性设置为重定向文件的名称AdRedirect.asp，同时广告主的主页URL和所用的图像添加到查询字符串中，因此当用户点击广告栏时，重定向文件将在服务器上载入并运行。
4．  重定向文件
重定向文件可以是一个ASP页面、一个ISAPI DLL或者是一个CGI应用程序，无论是哪一种，它必须能够接受和辨别广告主的主页URL以及图像名参数。它检查这些值并决定下一步该做什么。例如通常会把用户重新定向到与此广告栏有关的URL，这一点使用下面的VBScript代码很容易实现。
Response.Redirect Request.QueryString("url")
然而，重新定向文件提供给我们的不仅仅是这些。例如可以统计点击每个广告的用户数量，如果根据点击数收到广告费用的话，这将显得尤其有用。也可以用本章后面介绍的Counters组件来完成这项工作。
…
'get the URL of the advertiser's target page
strAdvertiserURL = Request.QueryString("url")
If Instr(strAdvertiserURL, "wrox.com") Then
   objCounters.Increment("wrox")
   Response.Clear
   Response.Redirect strAdvertiserURL
End If

If Instr(strAdvertiserURL, "going-to-the-moon") Then
   objCounters.Increment("lunar")
   Response.Clear
   Response.Write "Sorry, this isn't a real site..."
End If
…
.. 'same for other advertisers
…
查询字符串包含图像文件名时，在脚本中也要考虑这一点，如果在调度文件中，同一广告主有三种不同的图像，可以对每个图像单独地跟踪访问次数。
…
If Instr(strAdvertiserURL, "wrox.com") Then
'this is an advert for the Wrox Press site
       Select Case Request.QueryString("image")
              Case "books.gif"
                     objCounters.Increment("wrox_books")
              Case "website.gif"
                     objCounters.Increment("wrox_site")
              Case Else
                     objCounters.Increment("wrox_other")
       End Select
       Response.Clear
       Response.Redirect strAdvertiserURL
End If
…
5．  一个Ad Rotator示例页面
本章提供的示例文件包括一个Ad Rotator组件演示程序，它能够从前面见过的ASP Installable Components主菜单中打开。页面的上部显示的是一个由名为ad_schedule.txt的旋转调度文件定义的广告（可在本章示例目录下的Ad RotFiles子目录中找到ad_shedule.txt），如图6-5所示：

使用的代码前面已经讨论过，这里在调度文件中仅增加了另外一些条目，以便更清楚地显示载入页面时的广告的变化情况。如果点击一个广告，将运行名为ad_redirect.asp的重定向文件中的代码，并且相应的广告主的页面在新的窗口里打开。完成该工作的代码和前面见到的相同。
在重定向文件中，可使用计数器（由Counters组件创建）实例存储每个广告的点击次数。
…
If Instr(strAdvertiserURL, "wrox.com") Then
   objCounters.Increment("wrox")
   Response.Clear
   Response.Redirect strAdvertiserURL
End If
…此页面的其余部分演示了Counters组件的作用，下面介绍该组件。
6.2.4 Counters组件
       Counters组件能用于创建、存储、递增和检索每个计数器的值。不要把它和本章后面将要介绍的Page Counter组件混淆，Counters组件能用于支持任何种类数据的统计。
       一个计数器含有一个整数值，能通过Counters组件的方法进行运算。使用Set方法设置计数器的指定值，用Get方法检索计数器中的值，使用Increment方法使计数器的值加1，使用Remove方法删除一个计数器。所有的计数器的值存储在一个名为Counters.txt的文本文件中，可在Counters.dll组件所在的目录中找到该文件。
1．  Counters组件的成员
Counters组件提供了用于维护每个计数器组件中数值的四个方法，如表6-4所示：
表6-4  Counters组件方法及说明
方 法
说 明

Get(counter_name)
返回指定计数器的当前值，如果此计数器先前没有创建，道德创建并设置成0，其返回值为0

Increment(counter_name)
增加指定计数器的当前值，如果此计数器先前没有创建，首先创建并设置为1

Remove(counter_name)
删除指定的计数器

Ser(counter_name,value)
把指定计数器的值设置成参数value提供的整数值，如果此计数器先前没有创建，先创建并设定为指定值

2．  使用Counters组件
由于Counters.txt文件仅有一个所有组件实例都能访问的拷贝。因此，应该只创建单个的Counters组件实例，并且使之对Web网站的所有页面都是可用的，实现这一点的常用方法是在缺省Web站点根目录下的global.asa文件中创建一个应用程序范围的实例。
采用下面程序：
<!-- declare instance of the ASP Counters component with application-level scope
-->
<OBJECT ID="objCounters" RUNAT="Server" SCOPE="Application"
PROGID="MSWC.Counters">
</OBJECT>
可以使用Counters组件对需要完成的任务创建一个新的计数器。在下面的程序中，给出了有三项选择的调查问题，并对每一种选择的回答次数进行了统计，当使用者提交包含三项选择的窗体后，将调入这个页面。假设选项通过点击SUBMIT按钮的cmdYes、cmdNo和cmdMaybe来选择，其对应值分别是“是”、“否”和“可能”。
<% 'in VBScript”
If Request.Form("cmdYes") = "Yes" Then objCounter.Increment("Response_Yes")
If Request.Form("cmdNo") = "No" Then objCounter.Increment("Response_No")
If Request.Form("cmdMaybe") = "Maybe" Then
       objCounter.Increment("Response_Maybe")
%>
如果这是第一次收到一个指定的响应，程序将创建一个新的计数器并自动初始化为1。
计数器在使用范围上没有限制，因为Counters对象创建在文件global.asa中，这意味着在虚拟应用程序或Web网站中创建的任何一个页面中都是可用的，所以这个“调查计数器”可用在应用程序的任何页面上，记住单个的Counters对象能提供所需的许多独立计数器，不需要创建很多Counters对象实例。
在前面的Ad Rotator组件页面示例中，研究了如何使用Counters组件存储每个广告主的点击次数，也可以在页面中使用Counters组件的Get方法显示当前值。
Wrox Press: <B><% = objCounters.Get("wrox") %></B>

Stonebroom: <B><% = objCounters.Get("stonebroom") %></B>

Xtras: <B><% = objCounters.Get("xtras") %></B>

ComponentSource: <B><% = objCounters.Get("compsrc") %></B>

Four CDs: <B><% = objCounters.Get("fourcds") %></B>

Lunar: <B><% = objCounters.Get("lunar") %></B>

每次加载页面时，都自动更新计数器的当前值。然而页面也包含有一些控件能调用Counters组件的其他两个方法，即删除一个计数器（相当于将其设置为0）和将计数器设置成一个指定数值，如图6-6所示：

这些控件在一个<FORM>上，点击任何一个小的空白按钮时，此窗体便提交给同一个页面，方法与本章中的所有页面所用的几乎一样。下面的程序是为Remove方法创建控件的HTML代码。
<FORM ACTION="<% = Request.ServerVariables("SCRIPT_NAME") %>" METHOD="POST">

<INPUT TYPE="SUBMIT" NAME="cmdRemove" VALUE="   ">
  Counter.Remove ("
<SELECT NAME="lstRemove" SIZE="1">
  <OPTION VALUE="wrox">Wrox Press</OPTION>
  <OPTION VALUE="stonebroom">Stonebroom</OPTION>
  <OPTION VALUE="xtras">Xtras</OPTION>
  <OPTION VALUE="compsrc">ComponentSource</OPTION>
  <OPTION VALUE="fourcds">Four CDs</OPTION>
  <OPTION VALUE="lunar">Lunar</OPTION>
</SELECT> ")<P>
…
</FORM>
当载入页面时，通过检查Request.Form集合查看点击的按钮，如果找到了某个按钮，将运行代码的相应部分。在点击Remove按钮的情况下，相应的代码是：
       If Len(Request.Form("cmdRemove")) Then
  strCounterName = Request.Form("lstRemove")              'get the counter name
  objCounters.Remove strCounterName
  Response.Write "Removed counter '<B>" & strCounterName & "</B>'.<P>"
End If
对于Set方法，情况类似，但不仅仅需要从文本框中读取新值，而且在调用Set方法之前，检查文本框中的值是否是有效值。
If Len(Request.Form("cmdSet")) Then
  strCounterName = Request.Form("lstSet")              'get the counter name
  strNewValue = Request.Form("txtSet")                   'get the new value
  If IsNumeric(strNewValue) Then                           'if it can be converted to a number
     intNewValue = CInt(strNewValue)                    '… then convert it
     objCounters.Set strCounterName, intNewValue
     Response.Write "Set counter '<B>" & strCounterName & _
                    "</B>' to <B>" & strNewValue & "</B>.<P>"
  Else
     Response.Write "<B>'" & strNewValue & "</B>' is not a valid number.<P>"
  End If
End If
使用页面中的按钮调用Counters对象的方法时，重新载入时会在页面顶端看到一段信息和计数器中的新值，如图6-7所示：


6.2.5 Browser Capabilities组件
       创建各种Web网页时面临的问题之一是，不仅仅使用ASP技术创建动态网页，而且能够使用HTML元素和其他客户端技术，像Java Applets、ActiveX控件以及最近出现的HTML元素。需要意识到的是，一些访问者若使用了恰好不支持它们的浏览器，那么对于精心编制的网页，访问者看到的可能是文本、图像的杂乱组合，甚至更糟糕的还有相应工作的脚本程序代码。
       这里不讨论应当如何设计支持各种不同浏览器的网页（如果想了解这方面更多的内容，可以查阅Alex Homer编写的，Wrox出版的《Professional ASP Techniques for Webmasters》一书，书号是ISN 1-861001-79-7）。然而，确实要引用某个页面时，ASP和IIS提供铁Browser Capabilities服务器组件可以用来检测浏览器所支持的相关特征。
       用户请求来自服务器的页面时，浏览器传送的HTTP报头包含了正在使用的浏览器的细节。在HTTP-speak（它被称为用户代理字符串）中，定义了浏览器的名称、版本、操作系统及其兼容性。Browser Capabilities组件在自己的配置文件中查找这个字符串，并采用许多与浏览器特征等同的特性。因此，在网页运行的任何时候，Browser Capabilities组件能够提供支持或不支持某个特性的细节。
       在ASP 3.0版本中，Browser Capabilities组件增加了一个新特性。在ASP页面中包含METADATA指令，指示组件从浏览器中取出一个cookie，并把其包含的任意值添加到当前的组件实例中作为新属性。这提供了一种方法，从浏览器收集更多的用户特定的信息，而不仅仅是通常从browscap.ini文件中得到的浏览器指定的信息。了解了现有的浏览器检测特性如何工作后，再回头介绍新的METADATA技术。
1．  browscap.ini文件
Browser Capabilities组件使用一个基于服务器的browscap.ini文本文件，该文本文件必须和browscap.dll组件文件处于同一目录中。browscap.ini文件包含大多数关于以前和当前浏览器的信息，并且当浏览器的用户代理字符串与文件中的指定字符串都不匹配时，将使用browscap.ini文件中的缺省部分。所以添加关于浏览器的新信息或者更新现有的信息，只需编辑browscap.ini文件。
首先看一下browscap.ini文件的格式，该文件中的所有条目都是可选的。担包括缺省部分是非常重要的。如果使用的浏览器与browscap.ini文件中的任何一个都不匹配，并且没有指定缺省浏览器设置，那么所有的特性将设置成“UNKNOWN”。
下面是browscap.ini文件的格式：
; we can add comments anywhere, prefaced by a semicolon like this

; entry for a specific browser
[HTTPUserAgentHeader]
parent = browserDefinition
property1 = value1
property2 = value 2
…

[Default Browser capability Settings]
defaultProperty1 = defaultValue1
defaultProperty2 = defaultValue2
…
[HTTPUserAgentHeader]行定义了特定浏览器的起始段，并且Parent行指明了包含浏览器更多信息的另外一个定义。下面的各行定义了我们想通过Browser Capabilities组件可获得的属性以及对于该浏览器的相应值。如果浏览器没有列在所属段中，或者尽管列出了但没有列出所有的属性，将采用Default部分所列出的属性和相应的值。
例如，这个文件包含以[IE5.0]开头的段，这个段包含有Internet Explorer 5.0的相应值，这里没有parent行，显示的（除了那些在Default部分定义的）仅是我们显示定义的属性。
[IE 5.0]
browser=IE
Version=5.0
majorver=5
minorver=0
frames=TRUE
tables=TRUE
cookies=TRUE
backgroundsounds=TRUE
vbscript=TRUE
javascript=TRUE
javaapplets=TRUE
ActiveXcontrols=TRUE
Win16=False
beta=False
AK=false
SK=false
AOL=false
Update=False
此段描述不和任何一个浏览器相匹配，因为，HTTPUserAgentHeader行仅仅是[IE 5.0]。然而，如果把[IE 5.0]作为父代，可以对浏览器添加针对IE5的定义：
[Mozilla/4.0 (compatible; MSIE 5.*; Windows 95*)]
parent=IE 5.0
version=4.0
minorver=0
platform=Win95
这样我们把[IE 5.0]指定为浏览器的父代，则显式提供的属性将代替或增加给父代定义的相应的值，但这里也假定任何其他的属性值没有显式地列在其所属段中。
为了识别非常相似的浏览器版本，在HTTPUserAgentHeader行可以使用星号通配符，如：
[Mozilla/4.0 (compatible; MSIE 5.*; Windows 95*)]
将和下面的语句相匹配：
[Mozilla/4.0 (compatible; MSIE 5.0; Windows95)]
[Mozilla/4.0 (compatible; MSIE 5.5; Windows 95 AOL)]
…
然而，只有在浏览器发送的用户代理字符串和不含“*”的HTTPUserAgentHeader不完全匹配的情况下，才采用通配符匹配。也只有当这种测试失败了，字符串才会企图和含通配符的HTTPUserAgentHeader相匹配，并且使用文件中所找到的确实匹配的第一个值。
最后，加上缺省浏览器段：
[Default Browser Capability Settings]
browser=Default
Version=0.0
majorver=#0
minorver=#0
frames=False
tables=True
cookies=False
backgroundsounds=False
vbscript=False
javascript=False
javaapplets=False
ActiveXcontrols=False
…
这里假设一种最坏的情况，浏览器几乎什么都不支持。应在此基础上定义我们实际想要使用的值。但是，如果定义了一些缺省值为True，在一个UNIX终端上使用纯文本浏览器浏览页面时，可能达不到我们所希望的效果。
维护browscap.ini文件
关闭浏览器时，更新Browscap.ini文件中相应值使其与浏览器的特性保持一致，增加一些旧的或我们关注的专用的值显然也是非常重要的。为了给用户提供方便，通常可从Microsoft Web网站上下载支持ASP的一个相当全面的browscap.ini版本或其升级版本，而CrScape Inc公司提供的browscap.ini版本经常比Microsoft Web网站上的版本更新一些。
可以在http://www.cyscape.com/browscap/上找到最新的browscap.ini版本，并且订阅一份邮件列表就可自动地收到该文件的最新版本。CrScape公司也制作一个与Microsoft Browser Capabilities组件竞争的组件，称为browserHank（本章后面将介绍），新版的browscap.ini文件也可从http://www.asptracker.com上获得。
2．  使用Browser Capabilities组件
我们已经掌握了browscap.ini文件如何提供包含有关特定浏览器信息的可定制属性，下面介绍如何使用Browser Capabilities组件。相对而言，使用Browser Capabilities组件简单一些，下面创建组件的一个实例并说明其属性。
<% 'In VBScript:
Set objBCap = Server.CreateObject("MSWC.BrowserType")
blnVBScriptOK = objBCap.vbscript             'save the result in a variable
If blnVBScriptOK Then
       Response.Write "This browser supports VBScript"
Else
       Response.Write "This browser doesn't support VBScript"
End If
%>
上面代码程序检查浏览器是否支持VBScript并显示一个信息，可以想象这段代码根据浏览器给出的不同响应的网页，引导用户到不同的页面。
当然，使用Browser Capabilities组件的属性可做比这更复杂的工作，一个让人喜爱的技术是根据浏览器支持的属性为网站载入不同的索引网页。如果网站有一套使用帧（frame）的页面和一套不使用帧的页面，当用户第一次访问网站时，能够检查浏览器显示帧的能力，并将其重新定位到合适的索引网页上。
3．  使用Browser Capabilities的cookie特性
新版Browser Capabilities组件增加的特性之一是提供了一种方式,以获得更多的有关调用网页的特定客户的信息.
browscap.ini文件的信息只适用于特定类型的所有浏览器，所以组件仅能报告所安装的浏览器的共同特性，例如能知道浏览器是否支持cookie，但不能知道用户是否已在浏览器“选项”对话框中关闭了cookie。
同样，使用复杂的页面设计时，最好了解用户使用的连接类型，以便能选择大小适当的图像文件传送给他们，例如用户通过局域网（而不是调制解调器）连接，则允许我们提供更加丰富的环境。如果能知道用户采用的屏幕分辨率、浏览器所用的语言、操作系统和处理器类型等参数，对于我们的设计是有帮助的。
IE 5通过使用缺省行为提供这种信息，这是客户端网页的一个元素。IE 5中的行为是新增加的，其他的浏览器不支持，这是一种对网页中的元素添加特殊功能的方法，通过STYLE属性（或CSS风格表项）和元素联系起来。特别是，IE 5提供的clientCaps行为能用于提供有关客户机和浏览器设置以及当前选项的信息。
通过创建一种元素和与之相连的clientCaps行为，能通过该元素查询到有关客户的信息。下列页面来自我们提供的示例文件（browscap_cookie.htm）正是这样做的。它首先定义了应用于<IE:clientcaps>类型的所有元素的包含clientCaps行为的风格。这是XML语法，在<HTML>标记的XLMNS属生中使用为当前网页定义的名称空间。
然而，页面browscap_cookie.htm从应用clientCaps行为的元素得到一系列值，并且建立一个包含这些值的cookie，最后，把这个cookie分配给文档的cookie属性，以便有对这个特定服务器目录的页面请求时，将它传送给服务器。
<HTML XMLNS:IE>
<HEAD>
<STYLE>
IE:clientcaps {behavior:url(#default#clientcaps)}
</STYLE>
</HEAD>
<BODY ONLOAD="createCookie();">
<IE:clientcaps ID="objCCaps" />

<SCRIPT LANGUAGE="JavaScript">

function stopAllErrors() {
  return true; // prevent display of any errors
}

function createCookie() {
  window.onerror = stopAllErrors;
  var strCookie = new String();
  strCookie = 'width=' + objCCaps.width
            + '&height=' + objCCaps.height
            + '&availWidth=' + objCCaps.availWidth
            + '&availHeight=' + objCCaps.availHeight
            + '&bufferDepth=' + objCCaps.bufferDepth
            + '&colorDepth=' + objCCaps.colorDepth
            + '&javaEnabled=' + objCCaps.javaEnabled
            + '&cookieEnabled=' + objCCaps.cookieEnabled
            + '&connectionType=' + objCCaps.connectionType
            + '&platform=' + objCCaps.platform
            + '&cpuClass=' + objCCaps.cpuClass
            + '&systemLanguage=' + objCCaps.systemLanguage
            + '&userLanguage=' + objCCaps.userLanguage;
  document.cookie = 'BrowsCap=' + strCookie;
}
</SCRIPT>

</BODY>
</HTML>
为了使用这个cookie，只需把特定的METADATA指令插入到ASP页面中。如下所示：
<!-- METADATA TYPE="Cookie" NAME="BrowsCap"
                     SRC="browserCapabilities/browscap_cookie.htm"-->
现在，运行这个ASP网页时，会自动把页面browscap_cookie.htm发送给客户机，客户机便运行这个行为特性，然后返回cookie，随后Browser Capabilities组件把cookie的内容添加到组件实例的可用属性的列表中，查询方法与查询browscap.ini文件创建的属性所用的方法相同。
width: <B><% = objBCap.width %></B>

height: <B><% = objBCap.height %></B>

…
Browser Capabilities示例网页显示两类系列数值，一类是从由browscap.ini文件决定的属性中收集的数据，另一类来自客户端cookie页面。当然，不限于仅仅收集来自客户端页面中的clientCaps行为的值，使用动态HTML技术可以查询浏览器的任何属性或者是像navigator.appName这样的传统对象属性。Browser Capabilities组件示例页面如图6-8所示：


分享到
  • 微信分享
  • 新浪微博
  • QQ好友
  • QQ空间

上一篇ASP/IIS可安装组件二

下一篇脚本对象与服务器组件的比较

相关文章

点击：