小工具：计算当前文件夹中，有多少行JS代码和ASP代码，并且还可

2022-07-15 80酷酷网 80kuku.com

　　js|统计

计算当前文件夹中，有多少行JS代码和ASP代码，并且还可统计代码有多少字节

有示例代码

<%
'\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
'\\
'\\ from codeproject.com
'\\ calculate code
'\\ bluedestiny
'\\ mail:bluedestiny at 126.com
'\\
'\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

option explicit
response.buffer=false

class COUNT_CODE
private fso,spath
private asplines, jslines, aspbytes, jsbytes, aspwords
private sub class_initialize
'构造函数，新建一个fso实例
set fso = createobject("scripting.filesystemobject")
end sub
private sub class_terminate
set fso=nothing
end sub
private function iterate(path)
dim folder, folders, files, file, ts, txt, arr, f
set folder = fso.getfolder(path)
set files = folder.files
dim rx, c
'建立正则表达式，
'事实上，不应该写在这里，应该写在构造函数里(包括所用到的变体都应该放在构造函数里)，
'因为这里用的是递归，每次调用自身都重新建立正则实例，肯定降低了效率。在递归中尽量少的初始化值
'改我就不改了，有兴趣的话，用得着的朋友改改吧
set rx = new regexp
rx.ignorecase = true
rx.global = true
rx.pattern = " +"
'递归当前文件夹的文件。包括js和asp
for each file in files
   if right(file.name,4)=".asp" or right(file.name,3)=".js" then
    set ts = file.openastextstream
    if ts.atendofstream then txt = "" else txt = ts.readall
    ts.close
    txt = rx.replace(txt," ")
    txt = replace(txt,vbcrlf&vbcrlf,vbcrlf)
    arr = split(replace(txt,vbcrlf," ")," ")
    aspwords = aspwords + ubound(arr)
    arr = split(txt,vbcrlf)
    if right(file.name,4)=".asp" then
     asplines = asplines + ubound(arr)
     aspbytes = aspbytes + len(txt)
    else
     jslines = jslines + ubound(arr)
     jsbytes = jsbytes + len(txt)
    end if
   end if
next
'递归当前文件夹的所有子文件夹。
set folders = folder.subfolders
for each f in folders
   iterate f.path
next
end function

public property let path(s)
spath=server.mappath(s)
end property
public sub count
iterate(spath)
end sub
public sub printf
response.write "ASP:" & " "
response.write "Total Lines Coded: " & asplines & " "
response.write "Total Bytes: " & aspbytes & "" & " "
response.write "Total Individual Elements (words) Typed: " & aspwords & " "
response.write "JScript:" & " "
response.write "Total Lines Coded: " & jslines & " "
response.write "Total Bytes: " & jsbytes
end sub
end class

'\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
'\\示例代码
'\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\

dim o
set o=new COUNT_CODE
o.path="bluedestiny/"
o.count
o.printf
%>